Description Cedric Vidal 2010-11-29 15:39:38 EST

Build Identifier: I20100608-0911

The following grammar serializes correctly:

Expression : Addition;

Addition returns Expression :
    Multiplication ({Operation.left=current} op=OPERATOR_ADD right=Multiplication) *
    ;

Multiplication returns Expression :
    Literal ({Operation.left=current} op=OPERATOR_MUL right=Literal) *
    ;

Literal returns Expression:
    '(' Expression ')'
    | {IntLiteral} value=INT
    ;

terminal OPERATOR_MUL : '*'|'/';
terminal OPERATOR_ADD : '+'|'-';

When using rules instead of terminals, serialization fails to include parentheses:

Expression : Addition;

Addition returns Expression :
    Multiplication ({Operation.left=current} op=OPERATOR_ADD right=Multiplication) *
    ;

Multiplication returns Expression :
    Literal ({Operation.left=current} op=OPERATOR_MUL right=Literal) *
    ;

Literal returns Expression:
    '(' Expression ')'
    | {IntLiteral} value=INT
    ;

OPERATOR_MUL : '*'|'/'; // <-- using rules instead of terminals
OPERATOR_ADD : '+'|'-';

--> parentheses are not serialized

When operators are specific meta classes which are referenced, it also fails. The following DSL illustrates that. It adds the possibility to define operators and reference them.

Evaluation:
    (ops+=Operator ';') *
    'exp' exp=Expression
    ;

Expression : Addition;

Addition returns Expression :
    Multiplication ({Operation.left=current} op=[Operator|OPERATOR_ADD] right=Multiplication) *
    ;

Multiplication returns Expression :
    Literal ({Operation.left=current} op=[Operator|OPERATOR_MUL] right=Literal) *
    ;

Literal returns Expression:
    '(' Expression ')'
    | {IntLiteral} value=INT
    ;

terminal OPERATOR_MUL : '*'|'/';
terminal OPERATOR_ADD : '+'|'-';

Operator :
    'op' name=(OPERATOR_ADD|OPERATOR_MUL)
    ;

--> fails with "org.eclipse.xtext.conversion.ValueConverterException: The value '*' is an invalid OPERATOR_ADD"


Reproducible: Always